turtles-own
[
  node-clustering-coefficient
  distance-from-other-nodes   ;; list of distances of this node from other nodes
  rewired?                    ;; keeps track of whether the link has been rewired or not
  old-data
  data
  delta
  inputs
]

globals
[
  clustering-coefficient               ;; the clustering coefficient of the network
                                       ;; this is the average of clustering coefficients of all nodes
  average-path-length                  ;; average path length of the network
  infinity                             ;; a very large number.
                                         ;; used to denote distance between two nodes which
                                         ;; don't have a connected or unconnected path between them
  number-rewired                          ;; counter for number of edges that get rewired.  used for plots.
  correl
  base-freq
  kawachi-constant
  kawachi-prob
  isolated-nodes
  sorted-nodes
]

breed [ links link ]
breed [ nodes node ]

;;;;;;;;;;;;;;;;;;;;;;;;
;;;  Run Procedures  ;;;
;;;;;;;;;;;;;;;;;;;;;;;;

to go
    ask nodes [
      set old-data data
    ]
    ask nodes [
      let myval data
      
      set inputs map [sin ((? - myval) * 360)] ( values-from __link-neighbors [old-data] )
      set data (data + delta + multiplier * sum inputs)
      if (data < 0) [
        set data (data + 1)
      ]
      if (data >= 1) [
        set data (data - 1)
      ]      
      set color (hsb data 1 1)
    ]
    
    let sines sum (map [sin (? * 360)] ( values-from nodes [data] ) )
    let cosines sum (map [cos (? * 360)] ( values-from nodes [data] ) )
    let n count nodes
    set correl sqrt ( (sines * sines + cosines * cosines) / (n * n) )
    
    set-current-plot "Correlation"
    set-current-plot-pen "r"
    plot correl
end


;;;;;;;;;;;;;;;;;;;;;;;;
;;; Setup Procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;

to startup
  ;; nothing
end

to setup
  ca
  set infinity 99999  ;; just an arbitrary choice for a large number
  set base-freq 0.02
  set kawachi-constant 10
  set-default-shape turtles "circle"
  make-nodes
  set sorted-nodes (sort nodes)
  
  let success? false
  
  while [not success?] [
      ask links [ die ]
      wire-them
      rewire-kawachi
      set success? do-calculations
  ]
  
  ask nodes [
    set data (random-float 1)
    set delta base-freq + (random-float spread) - (spread / 2)
    set old-data -1
  ]
  repeat 100 [__layout-spring nodes 0.2 (1 + 2 * kawachi-parameter) 1]
end


to make-nodes
  create-custom-nodes num-nodes
  [
    set color gray + 2
    ;; they will form a circle
    fd max-pxcor - 1
  ]
end

;;;;;;;;;;;;;;;;;;;;;;;
;;; Main Procedure ;;;
;;;;;;;;;;;;;;;;;;;;;;;

to rewire-kawachi
    set isolated-nodes []
    set number-rewired 0
    set kawachi-prob (kawachi-parameter / kawachi-constant)
    repeat kawachi-constant [ rewire-phase ]
end

to rewire-phase
    ask links [
      set rewired? false
    ]
    
    ask links [
      if (random-float 1) < kawachi-prob [
        set rewired? true
      ]
    ]

    let deletables (links with [ rewired? ] ) 
    
    ask deletables [
        set rewired? false
    ]
    
    ask deletables [
        without-interruption [
            my-rewire
        ]
    ]
end


to my-rewire
  let node1  __end1
  let node2  __end2
  let deg1 value-from node1 [ count __link-neighbors ]
  let deg2 value-from node2 [ count __link-neighbors ]
  
  ;; network links x–y are replaced with probability p/10 by links x–z
  ;; where the node x has a higher degree than y, and the node z is chosen
  ;; to be an isolated node from a previous rewiring (if there are any), or
  ;; chosen randomly (with probability proportional to the degree of nodes plus one) otherwise
  
  if (deg1 < deg2) [
    ;; swap so deg1 is higher, and node1 will be retained
    let temp deg1
    set deg1 deg2
    set deg2 temp
    let tempn node1
    set node1 node2
    set node2 tempn
  ]
    
  if (deg2 = 1) [ set isolated-nodes (lput node2 isolated-nodes) ]
  if (deg1 = 1) [ set isolated-nodes (lput node1 isolated-nodes) ]
  
  let new-node nobody
  let hood value-from node1 [ __link-neighbors ]
  
  if (not empty? isolated-nodes) [
    set new-node (item 0 isolated-nodes)
    ifelse (member? new-node hood) [
      set new-node nobody
    ] [
      set isolated-nodes (but-first isolated-nodes)
    ]
  ]
  
  if (new-node = nobody) [
    ;; choose new node
    let biases ( map [ifelse-value (? = node1 or member? ? hood) [ 0 ] [ 1 + count __link-neighbors ] ] sorted-nodes )
    let sb (sum biases)
    let p (random-float sb)

    let sumb 0
    let done? false
    (foreach biases sorted-nodes [
      if (not done?) [
        set sumb (sumb + ?1)
        if (p < sumb and ?1 > 0) [
          set new-node ?2
          set done? true
        ]
      ]
    ])
  ]
          
  if (new-node = nobody) [
    user-message "Error: failed to identify new node in Kawachi rewiring"
  ]
    
  replace node1 node2 new-node
  
  set number-rewired (number-rewired + 1)  ;; counter for number of rewirings
end


to replace [a b new-b]
  ask a [ __create-link-with new-b [ set color brown  set rewired? true ] ]
  ask a [ __remove-link-with b ]
end			


to-report do-calculations
  
  ;; set up a variable so we can report if the network is disconnected
  let connected? true
  
  ;; find the path lengths in the network
  find-path-lengths
  
  ;; check whether network got disconnected and ignore those runs (should not happen often);
  ;; we only want to calculate average path length when we have one connected component
  if (sum values-from nodes [length remove infinity distance-from-other-nodes] ) != (count nodes * count nodes )
  [
      ;; report that the network is not connected
      set connected? false
  ]
  set average-path-length (sum values-from nodes [sum remove infinity distance-from-other-nodes])
                          / (sum values-from nodes [length remove infinity distance-from-other-nodes] )
  ;; find the clustering coefficient and add to the aggregate for all iterations
  find-clustering-coefficient
  
  ;; report whether the network is connected or not
  report connected?
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Clustering computations ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to-report in-neighborhood? [ hood ]
  report ( member? __end1 hood and member? __end2 hood )
end


to find-clustering-coefficient
  ifelse not any? nodes with [count __link-neighbors > 1]
  [
    ;; it is undefined
    ;; what should this be?
    set clustering-coefficient 0
  ]
  [
    let total 0
    ask nodes with [ count __link-neighbors <= 1]
      [ set node-clustering-coefficient "undefined" ]
    ask nodes with [ count __link-neighbors > 1]
    [
      let hood __link-neighbors
      set node-clustering-coefficient (2 * count links with [ in-neighborhood? hood ] / 
                                         (count hood) * (count hood - 1) )
      ;; find the sum for the value at nodes
      set total total + node-clustering-coefficient
    ]
    ;; take the average
    set clustering-coefficient total / count nodes with [count __link-neighbors > 1]
  ]
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Path length computations ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;; Implements the Floyd Warshall algorithm for All Pairs Shortest Paths
;; It is a dynamic programming algorithm which builds bigger solutions
;; from the solutions of smaller subproblems using memoization that
;; is storing the results.
;; It keeps finding incrementally if there is shorter path through
;; the kth node.
;; Since it iterates over all nodes through k,
;; so at the end we get the shortest possible path for each i and j.

to find-path-lengths
  ;; reset the distance list
  ask nodes
  [
    set distance-from-other-nodes []
  ]

  let i 0
  let j 0
  let k 0
  let node1 one-of nodes
  let node2 one-of nodes
  let node-count count nodes
  ;; initialize the distance lists
  while [i < node-count]
  [
    set j 0
    while [j < node-count]
    [
      set node1 turtle i
      set node2 turtle j
      ;; zero from a node to itself
      ifelse i = j
      [
        set distance-from-other-nodes-of node1 lput 0 distance-from-other-nodes-of node1
      ]
      [
        ;; 1 from a node to it's neighbor
        ifelse value-from node2 [ __link-neighbor? node1 ]
        [
          set distance-from-other-nodes-of node1 lput 1 distance-from-other-nodes-of node1
        ]
        ;; infinite to everyone else
        [
          set distance-from-other-nodes-of node1 lput infinity distance-from-other-nodes-of node1
        ]
      ]
      set j j + 1
    ]
    set i i + 1
  ]
  set i 0
  set j 0
  let dummy 0
  while [k < node-count]
  [
    set i 0
    while [i < node-count]
    [
      set j 0
      while [j < node-count]
      [
        ;; alternate path length through kth node
        set dummy ( (item k distance-from-other-nodes-of turtle i) + (item j distance-from-other-nodes-of turtle k))
        ;; is the alternate path shorter?
        if dummy < (item j distance-from-other-nodes-of turtle i)
        [
          set distance-from-other-nodes-of turtle i replace-item j distance-from-other-nodes-of turtle i dummy
        ]
        set j j + 1
      ]
      set i i + 1
    ]
    set k k + 1
  ]

end

;;;;;;;;;;;;;;;;;;;;;;;
;;; Edge Operations ;;;
;;;;;;;;;;;;;;;;;;;;;;;

;; creates a new lattice
to wire-them
  ;; iterate over the nodes
  let n 0
  while [n < count nodes]
  [
    ;; make edges with the next two neighbors
    ;; this makes a lattice with average degree of 4
    make-edge turtle n
              turtle ((n + 1) mod count nodes)
    make-edge turtle n
              turtle ((n + 2) mod count nodes)
    set n n + 1
  ]
end


;; connects the two nodes
to make-edge [node1 node2]
  ask node1 [ __create-link-with node2  [
    set color gray    set rewired? false
  ] ]
end




; *** NetLogo 3.1.2 Model Copyright Notice ***
;
; Copyright 2007 by the Commonwealth of Australia.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from the Commonwealth of Australia (contact Anthony Dekker).
;
;
;
;
; PARTS OF THIS MODEL ARE BASED ON CODE TO WHICH THE FOLLOWING APPLIES
;
; Copyright 2005 by Uri Wilensky.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2005).  NetLogo Small Worlds model.
; http://ccl.northwestern.edu/netlogo/models/SmallWorlds.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 2005 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlogo/models/SmallWorlds
; for terms of use.
;
; *** End of NetLogo 3.1.2 Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
310
71
670
452
17
17
10.0
1
10
1
1
1
0
0
0
1
-17
17
-17
17

CC-WINDOW
5
468
679
563
Command Center
0

SLIDER
9
319
276
352
num-nodes
num-nodes
8
120
60
2
1
NIL

PLOT
12
13
276
192
Correlation
NIL
NIL
0.0
1.0
0.0
1.0
true
true
PENS
"r" 1.0 2 -65485 true

SLIDER
9
274
275
307
kawachi-parameter
kawachi-parameter
0
5
0.5
0.01
1
NIL

BUTTON
509
16
642
49
Run Simulation
go
T
1
T
OBSERVER
T
NIL

MONITOR
13
211
142
260
Average Distance
average-path-length
3
1

BUTTON
335
16
469
49
Create Network
setup
NIL
1
T
OBSERVER
T
NIL

SLIDER
10
368
277
401
multiplier
multiplier
1.0E-4
0.01
0.0010
1.0E-4
1
NIL

SLIDER
11
421
277
454
spread
spread
0
0.01
0.0010
1.0E-4
1
NIL

MONITOR
152
212
275
261
Correlation
correl
3
1

@#$#@#$#@
WHAT IS IT?
-----------
This model extends the Watts rewiring process to the Kawachi process, and runs a simulation of the Kuramoto model on the resulting network.


HOW TO USE IT
-------------
The KAWCHI-PARAMETER and NUM-NODES sliders control the network creation.

The MULTIPLIER and SPREAD sliders control the Kuramoto simulation.

The phases of the nodes are visualised as colours, and the correlation between the phases of nodes is plotted.


CREDITS
-------
This model was created by modifying Uri Wilensky's Small Worlds model (2005): http://ccl.northwestern.edu/netlogo/models/SmallWorlds.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.1.2
@#$#@#$#@
setup
repeat 5 [rewire-one]
@#$#@#$#@
@#$#@#$#@
<experiments>
  <experiment name="vary-kawachi" repetitions="2" runMetricsEveryTick="false">
    <setup>setup</setup>
    <go>go</go>
    <timeLimit ticks="1000"/>
    <metric>correl</metric>
    <enumeratedValueSet variable="kawachi-parameter">
      <value value="0"/>
      <value value="0.01"/>
      <value value="0.02"/>
      <value value="0.05"/>
      <value value="0.1"/>
      <value value="0.2"/>
      <value value="0.5"/>
      <value value="1"/>
      <value value="2"/>
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="spread">
      <value value="1.0E-4"/>
      <value value="3.0E-4"/>
      <value value="0.0010"/>
      <value value="0.0030"/>
      <value value="0.01"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@